home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib11.dsk / QUASAR II.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  70 lines
  1. 0  PRINT  CHR$(4)"BLOAD QUASAR.SHAPES": PRINT  CHR$(4)"BLOAD QUASAR.OBJ"
  2. 1  REM  *************************
  3. 2  REM  * QUASAR II             *
  4. 3  REM  * COPYRIGHT (C) 1982    *
  5. 4  REM  * BY MICRO-SPARC INC    *
  6. 5  REM  * LINCOLN, MA. 01773    *
  7. 6  REM  *************************
  8. 10  GOSUB 5000
  9. 20  GOSUB 4000
  10. 30  CALL 16384
  11. 40  ON  PEEK(20606) GOSUB 2000,3000
  12. 50  GOTO 20
  13. 1999  REM ---SHIP DESTROYED
  14. 2000 S = S -1: VTAB 22: HTAB 39: PRINT S;
  15. 2010  IF S >0  THEN  RETURN 
  16. 2020  POP : TEXT : VTAB 23: HTAB 4: PRINT "WOULD YOU LIKE TO PLAY AGAIN?";: POKE  -16368,0: GET A$
  17. 2030  IF A$ = "N"  THEN  HOME : END 
  18. 2040  GOTO 10
  19. 2999  REM ---QUADRANT CLEARED
  20. 3000 Q = Q +1
  21. 3010  VTAB 23: HTAB 8: PRINT "ADVANCING TO QUADRANT "Q;
  22. 3015  IF  INT(Q/4) = Q/4  THEN TNE = 20604:SOUND = 17565: FOR Z1 = 200 TO 230: FOR Z2 = 1 TO 10: POKE TNE,255 -Z1: CALL SOUND: NEXT : NEXT :S = S +2: GOSUB 2000
  23. 3020  RETURN 
  24. 3999  REM ---INIT,PART 2
  25. 4000  HGR : VTAB 22: HTAB 1
  26. 4010  PRINT "SCORE:"; SPC( 6);"QUADRANT:"; SPC( 6);"SHIPS LEFT:";
  27. 4020  HTAB 7: PRINT  PEEK(20600) + PEEK(20601) *256;
  28. 4030  HTAB 22: PRINT Q;: HTAB 39: PRINT S;
  29. 4040 NUM = 3 +Q: IF NUM >15  THEN NUM = 15
  30. 4050 SPD = Q/4: IF SPD >4  THEN SPD = 4
  31. 4060  FOR I = 0 TO NUM
  32. 4070  ON  INT( RND(1) *4 +1) GOTO 4080,4090,4100,4110
  33. 4080 X =  RND(1) *240 +10:Y =  RND(1) *5 +5: GOTO 4120
  34. 4090 X =  RND(1) *5 +5:Y =  RND(1) *140 +10: GOTO 4120
  35. 4100 X =  RND(1) *240 +10:Y = 155 - RND(1) *5: GOTO 4120
  36. 4110 X = 250 - RND(1) *5:Y =  RND(1) *140 +10
  37. 4120  POKE 20480 +I,X: POKE 20496 +I,Y
  38. 4130 X =  RND(1) *SPD +1: IF  RND(1) <.5  THEN X = 256 -X
  39. 4140  POKE 20512 +I,X
  40. 4150 Y =  RND(1) *SPD +1: IF  RND(1) <.5  THEN Y = 256 -Y
  41. 4160  POKE 20528 +I,Y
  42. 4170 X =  INT( RND(1) *6 +1): IF X = 4  THEN 4170
  43. 4180  POKE 20544 +I,X: POKE 20560 +I,1
  44. 4190  NEXT 
  45. 4200  POKE 20584,127: POKE 20585,80: POKE 20586,0: POKE 20587,0
  46. 4210  POKE 20590,0: POKE 20599,0: POKE 20605,NUM: POKE 20606,0: POKE 20607,NUM
  47. 4220  POKE  -16368,0
  48. 4230  VTAB 23: HTAB 1: CALL  -868
  49. 4240  RETURN 
  50. 4999  REM ---INIT,PART 1
  51. 5000  POKE 20600,0: POKE 20601,0:Q = 1:S = 3: SCALE= 1
  52. 5010  TEXT : HOME : NORMAL : POKE 216,0
  53. 5020  HOME : INVERSE : HTAB 16: PRINT "QUASAR ]" CHR$(91): NORMAL 
  54. 5030  VTAB 3: HTAB 12: PRINT "BY BRENT IVERSON"
  55. 5040  VTAB 5: HTAB 6: PRINT "WOULD YOU LIKE INSTRUCTIONS?";: GET A$: HTAB 1: CALL  -868
  56. 5050  IF A$ = "N"  THEN  HOME : RETURN 
  57. 5060  VTAB 3: HTAB 1
  58. 5070  PRINT "     DEEP IN THE ANDROMEDA NEBULA, A    QUASAR HAS EXPLODED, SPREADING DEBRIS INALL DIRECTIONS."
  59. 5080  PRINT : PRINT "    YOUR MISSION IS TO ENTER THE NEBULA,CLEARING AS MANY QUADRANTS OF DEBRIS AS YOU CAN WITH THE THREE SHIPS ALLOTTED TOYOU."
  60. 5100  PRINT : PRINT  SPC( 8)"TO MOVE" SPC( 8)"TO FIRE"
  61. 5110  PRINT  SPC( 8)"-------" SPC( 8)"-------"
  62. 5130  PRINT  SPC( 11)"W" SPC( 14)"I"
  63. 5140  PRINT  SPC( 11)"." SPC( 14)"."
  64. 5150  PRINT  SPC( 9)"A...D" SPC( 10)"J...L"
  65. 5160  PRINT  SPC( 11)"." SPC( 14)"."
  66. 5170  PRINT  SPC( 11)"X" SPC( 14)","
  67. 5180  PRINT : PRINT "    EACH PARTICLE OF DEBRIS THAT YOU HITIS WORTH ONE POINT."
  68. 5190  PRINT : PRINT  SPC( 7)"<PRESS ANY KEY TO START>"
  69. 5200  POKE  -16368,0: WAIT  -16384,128
  70. 5210  HOME : RETURN